blob: 1bc5a3f37c0910bd40f1178dc17e18069f7e8982 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
MY_PN="${PN}"-core
MY_P="${MY_PN}"-"${PV}"
inherit cmake dot-a toolchain-funcs
DESCRIPTION="High-performance, full-featured text search engine based off of lucene in C++"
HOMEPAGE="https://clucene.sourceforge.net"
SRC_URI="https://downloads.sourceforge.net/project/${PN}/${MY_PN}-unstable/$(ver_cut 1-2)/${MY_P}.tar.gz"
S="${WORKDIR}/${MY_PN}-${PV}"
LICENSE="|| ( Apache-2.0 LGPL-2.1 )"
SLOT="1"
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
IUSE="debug doc static-libs"
RESTRICT="test"
BDEPEND="doc? ( >=app-text/doxygen-1.4.2 )"
DOCS=(AUTHORS ChangeLog README README.PACKAGE REQUESTS)
PATCHES=(
"${FILESDIR}/${P}-fix-clang.patch"
"${FILESDIR}/${P}-contrib.patch"
"${FILESDIR}/${P}-pkgconfig.patch"
"${FILESDIR}/${P}-gcc6.patch"
"${FILESDIR}/${P}-gmtime.patch"
"${FILESDIR}/${P}-musl-pthread.patch"
"${FILESDIR}/${P}-libcxx.patch"
"${FILESDIR}/${P}-fix-binary-function.patch"
"${FILESDIR}/${P}-cmake4.patch"
)
src_prepare() {
cmake_src_prepare
# patch out installing bundled boost headers, we build against system one
sed -i \
-e '/ADD_SUBDIRECTORY (src\/ext)/d' \
CMakeLists.txt || die
# don't reference non-existent paths in .pc file (bug #950316)
sed -i \
-e 's%\(:\| -I\)${prefix}/include/CLucene/ext%%g' \
./src/core/libclucene-core.pc.cmake || die
rm -rf src/ext || die
# do compile-only tests while cross-compiling
# the EXITCODE for each test can be overrided otherwise
if tc-is-cross-compiler; then
sed -i \
-e '/CHECK_CXX_SOURCE_/s/_RUNS/_COMPILES/' \
src/shared/cmake/*.cmake || die
fi
}
src_configure() {
use static-libs && lto-guarantee-fat
# Disabled threads: see upstream bug
# https://sourceforge.net/p/clucene/bugs/197/
local mycmakeargs=(
-DENABLE_ASCII_MODE=OFF
-DENABLE_PACKAGING=OFF
-DDISABLE_MULTITHREADING=OFF
-DBUILD_CONTRIBS_LIB=ON
-DLIB_DESTINATION="${EPREFIX}/usr/$(get_libdir)"
-DENABLE_DEBUG=$(usex debug)
-DENABLE_CLDOCS=$(usex doc)
-DBUILD_STATIC_LIBRARIES=$(usex static-libs)
)
cmake_src_configure
}
src_install() {
cmake_src_install
use static-libs && strip-lto-bytecode
}
|
