dev-python/plotly: Bump to 7.1.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 112 insertions, 0 deletions

diff --git a/dev-python/plotly/Manifest b/dev-python/plotly/Manifest
index 6a7480a6042a..a53d3ef10510 100644
--- a/dev-python/plotly/Manifest
+++ b/dev-python/plotly/Manifest
@@ -1 +1,2 @@
 DIST plotly.py-7.0.0.gh.tar.gz 9588726 BLAKE2B f725857ed1e645861b364697f0766b5aa750f04683736e9879bf0ebb70bd326af4a53ab862fe884c3e16e14958d86eee13f06d4d0e6d5b48c9b51a8c77f96ae2 SHA512 54fb04dd442f5deb2c18fdd78f8d74f76040dbf3af7451807c5567d86376fb72c995ac54c69acdfa86b369a078da300a5729f38bd506ac2760b1e8c96dc86761
+DIST plotly.py-7.1.0.gh.tar.gz 10239984 BLAKE2B d94c0d51c1d810c508b6a42567d8bb96bc47df7dd905f30a7557169a321505c92a6c0138702141766eaec1464ac1dcdd887f4a2ed611e65d5fd01a07db90fd43 SHA512 21527325f66e5cec00c98be740db89a5ecc53a057ffdb99950a3cbf915ac7188bdf346936308a57526e9cf14b6f30442c45a209635386c0abaec1f4c16c55707
diff --git a/dev-python/plotly/plotly-7.1.0.ebuild b/dev-python/plotly/plotly-7.1.0.ebuild
new file mode 100644
index 000000000000..dae3a8e7f288
--- /dev/null
+++ b/dev-python/plotly/plotly-7.1.0.ebuild
@@ -0,0 +1,111 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{12..14} )
+DISTUTILS_USE_PEP517=hatchling
+
+inherit distutils-r1
+
+MY_P=plotly.py-${PV/_}
+DESCRIPTION="Browser-based graphing library for Python"
+HOMEPAGE="
+	https://plotly.com/python/
+	https://github.com/plotly/plotly.py/
+	https://pypi.org/project/plotly/
+"
+SRC_URI="
+	https://github.com/plotly/plotly.py/archive/refs/tags/v${PV/_}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S="${WORKDIR}/${MY_P}"
+# The tests are not included in the PyPI tarball, to use the GitHub tarball
+# we have to skip npm, which means that the resulting install will
+# unfortunately lack the jupyterlab extension.
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/narwhals-1.15.1[${PYTHON_USEDEP}]
+	dev-python/packaging[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/jupyter[${PYTHON_USEDEP}]
+		dev-python/jupyterlab[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/numpy[${PYTHON_USEDEP}]
+		dev-python/pandas[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP}]
+		dev-python/psutil[${PYTHON_USEDEP}]
+		dev-python/pyarrow[${PYTHON_USEDEP}]
+		dev-python/pytz[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/scikit-image[${PYTHON_USEDEP}]
+		dev-python/scipy[${PYTHON_USEDEP}]
+		dev-python/statsmodels[${PYTHON_USEDEP}]
+		dev-python/xarray[${PYTHON_USEDEP}]
+	)
+"
+
+# There are sphinx docs but we are missing a bunch of dependencies.
+# distutils_enable_sphinx ../../../doc/apidoc
+
+EPYTEST_PLUGINS=()
+# xdist is causing pretty nasty race conditions here
+distutils_enable_tests pytest
+
+EPYTEST_IGNORE=(
+	# requires polars
+	tests/test_optional/test_px
+
+	# requires kaleido
+	tests/test_optional/test_kaleido/test_kaleido.py
+)
+
+EPYTEST_DESELECT=(
+	# requires polars
+	'tests/test_plotly_utils/validators/test_fig_deepcopy.py::test_deepcopy_dataframe[polars]'
+
+	# require anywidgets
+	'tests/test_io/test_to_from_json.py::test_from_json_output_type[FigureWidget-FigureWidget0]'
+	'tests/test_io/test_to_from_json.py::test_from_json_output_type[FigureWidget-FigureWidget1]'
+	'tests/test_io/test_to_from_json.py::test_read_json_from_filelike[FigureWidget-FigureWidget0]'
+	'tests/test_io/test_to_from_json.py::test_read_json_from_filelike[FigureWidget-FigureWidget1]'
+	'tests/test_io/test_to_from_json.py::test_read_json_from_pathlib[FigureWidget-FigureWidget0]'
+	'tests/test_io/test_to_from_json.py::test_read_json_from_pathlib[FigureWidget-FigureWidget1]'
+	'tests/test_io/test_to_from_json.py::test_read_json_from_file_string[FigureWidget-FigureWidget0]'
+	'tests/test_io/test_to_from_json.py::test_read_json_from_file_string[FigureWidget-FigureWidget1]'
+
+	# minor matplotlib incompatibility
+	plotly/matplotlylib/mplexporter/tests/test_basic.py::test_legend_dots
+	plotly/matplotlylib/mplexporter/tests/test_utils.py::test_linestyle
+
+	# fails in non-isolated env
+	test_init/test_dependencies_not_imported.py::test_dependencies_not_imported
+	test_init/test_lazy_imports.py::test_lazy_imports
+
+	# TODO
+	'tests/test_plotly_utils/validators/test_colorscale_validator.py::test_acceptance_named[Inferno_r]'
+
+	# numpy 2.4
+	tests/test_optional/test_figure_factory/test_figure_factory.py::TestViolin::test_violin_fig
+	tests/test_optional/test_utils/test_utils.py::TestJSONEncoder::test_encode_customdata_datetime_homogeneous_dataframe
+	tests/test_optional/test_utils/test_utils.py::TestJSONEncoder::test_encode_customdata_datetime_series
+	tests/test_optional/test_utils/test_utils.py::TestJSONEncoder::test_numpy_datetime64
+)
+
+src_prepare() {
+	distutils-r1_src_prepare
+
+	# stop installing junk "js" package
+	sed -i -e '/used by Jupyter extension/d' pyproject.toml || die
+}
+
+src_configure() {
+	# Do not try to fetch stuff with npm
+	export SKIP_NPM=1
+}