dev-python/python-tests: Bump to 3.15.9999

Signed-off-by: Michał Górny <mgorny@gentoo.org>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/853

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-python/python-tests/python-tests-3.15.9999.ebuild b/dev-python/python-tests/python-tests-3.15.9999.ebuild
new file mode 100644
index 000000000000..f40b251155a4
--- /dev/null
+++ b/dev-python/python-tests/python-tests-3.15.9999.ebuild
@@ -0,0 +1,60 @@
+# Copyright 2024-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_15 )
+
+inherit git-r3 python-r1
+
+PYVER=$(ver_cut 1-2)
+PATCHSET="python-gentoo-patches-3.15.0b1"
+
+DESCRIPTION="Test modules from dev-lang/python"
+HOMEPAGE="
+	https://www.python.org/
+	https://github.com/python/cpython/
+"
+SRC_URI="
+	https://distfiles.gentoo.org/pub/proj/python/patchsets/${PYVER%t}/${PATCHSET}.tar.xz
+"
+EGIT_REPO_URI="https://github.com/python/cpython.git"
+EGIT_BRANCH=${PYVER}
+S="${WORKDIR}/${P}/Lib"
+
+LICENSE="PSF-2"
+SLOT="${PYVER}"
+# enable by default to help CI handle it (we have no additional deps)
+IUSE="+python_targets_${PYTHON_COMPAT[0]}"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	~dev-lang/python-${PV}:${PYVER}
+"
+BDEPEND="
+	${PYTHON_DEPS}
+"
+
+src_unpack() {
+	git-r3_src_unpack
+	default
+}
+
+src_prepare() {
+	local PATCHES=(
+		"${WORKDIR}/${PATCHSET}"
+	)
+
+	cd .. || die
+	default
+}
+
+src_install() {
+	python_setup
+	# keep in sync with TESTSUBDIRS in Makefile.pre.in
+	python_moduleinto "/usr/lib/python${PYVER}"
+	python_domodule test
+	python_moduleinto "/usr/lib/python${PYVER}/idlelib"
+	python_domodule idlelib/idle_test
+}